https://linked.ope...aph-browser/query
| - PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX av: <https://linked.opendata.cz/resource/vocabulary/knowledge-graph-browser/wikidata/scientists/>
PREFIX browser: <https://linked.opendata.cz/ontology/knowledge-graph-browser/>
CONSTRUCT {
?parent a av:scientist ;
rdfs:label ?parentLabel ;
browser:class "scientist", ?parentSexClass .
?child a av:scientist ;
rdfs:label ?childLabel ;
browser:class "scientist", ?childSexClass .
?spouse a av:scientist ;
rdfs:label ?spouseLabel ;
browser:class "scientist", ?spouseSexClass .
?node av:parent ?parent ;
av:spouse ?spouse .
?child av:parent ?node .
av:parent browser:class ?parentClass .
av:spouse browser:class ?spouseClass .
} WHERE {
{
?node wdt:P22 ?parent .
BIND("family" AS ?parentClass)
?parent wdt:P106/wdt:P279* wd:Q901 .
?parent wdt:P21 ?sex .
BIND(IF(?sex=wd:Q6581072, "female", IF(?sex=wd:Q6581097, "male", "unknownsex")) AS ?parentSexClass)
} UNION {
?node wdt:P25 ?parent .
BIND("family" AS ?parentClass)
?parent wdt:P106/wdt:P279* wd:Q901 .
?parent wdt:P21 ?sex .
BIND(IF(?sex=wd:Q6581072, "female", IF(?sex=wd:Q6581097, "male", "unknownsex")) AS ?parentSexClass)
} UNION {
?node wdt:P40 ?child .
?child wdt:P106/wdt:P279* wd:Q901 .
BIND("family" AS ?parentClass)
?child wdt:P21 ?sex .
BIND(IF(?sex=wd:Q6581072, "female", IF(?sex=wd:Q6581097, "male", "unknownsex")) AS ?childSexClass)
} UNION {
?node wdt:P26 ?spouse .
?spouse wdt:P106/wdt:P279* wd:Q901 .
BIND("family" AS ?spouseClass)
?spouse wdt:P21 ?sex .
BIND(IF(?sex=wd:Q6581072, "female", IF(?sex=wd:Q6581097, "male", "unknownsex")) AS ?spouseSexClass)
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
|